技術資料

Movable Type のプラグインの作り方の解説記事、第五回です。

過去の記事は、

• Movable Typeプラグイン開発入門：第一回 基本的なプラグインの作成方法
• Movable Typeプラグイン開発入門：第二回 設定画面の実装と動作確認
• Movable Typeプラグイン開発入門：第三回 管理画面サイドメニューの変更と追加方法
• Movable Typeプラグイン開発入門：第四回 管理画面へのモード追加と設定表示の実装

今回は、第四回で実装した設定表示の動作モードと同等の機能を、別CGIスクリプトで実装する方法を解説します。

CGIスクリプトの作成

まずは、Movable Typeのプラグインとは別のCGIスクリプトを作成します。ここでは、mt/plugins/SamplePlugin/show_setting.cgiという名前で作成します。

#!/usr/bin/perl -w
use strict;

use lib '../../lib';
use lib '../../extlib';

use MT::Bootstrap App => 'SamplePlugin::PluginSetting';

上記のスクリプトは、mt/plugins/SamplePlugin/lib/SamplePlugin/PluginSetting.pmを実行するCGIスクリプトです。

Perlモジュール PluginSetting.pm の作成

次に、前回作成したPuginSetting.pmを以下のように修正します。

package SamplePlugin::PluginSetting;
use strict;
use warnings;

use base qw( MT::App );

sub init_request {
    my $app = shift;
    $app->SUPER::init_request(@_);
    $app->add_methods(
        main => \&show_setting,
        show_setting => \&show_setting,
    );
    $app->{default_mode}   = 'main';
    $app->{requires_login} = 0;
}

sub show_setting {
    my $app = shift;
    my $plugin = MT->component('SamplePlugin');

    my %param;
    eval{
        # プラグイン設定を取得
        $param{api_key} = $plugin->get_config_value('sample_api_key', 'system');
        $param{api_enable} = $plugin->get_config_value('sample_api_enable', 'system');
    };
    if($@){
        print "Content-Type: text/html\n\n";
        print "プラグイン設定の取得に失敗しました。: $@";
        return;
    }

    $app->load_tmpl('sampleplugin_showsetting.tmpl', \%param);
}

1;

init_requestメソッドで、$app->{requires_login}に0を設定しています。これにより、MTへのログインを必要としないCGIスクリプトとして動作します。
※APIキーを表示するCGIなので、認証が不要であるのはセキュリティ的によろしくないですが、今回は解説のためにこのようにしています。

show_settingメソッドは、前回の記事で作成したものと同じです。

また、show_settingメソッドで表示するテンプレートファイルsampleplugin_showsetting.tmplも、前回の記事で作成したものと同じものを使用できます。

動作確認

ブラウザでhttp://hostname/mt/plugins/SamplePlugin/show_setting.cgiにアクセスして、プラグインの設定画面が表示されることを確誩してください。